Hive05-DML

数据导入

向表中装载数据（Load）

hive> load data [local] inpath '/opt/module/datas/student.txt' [overwrite] | into table student [partition (partcol1=val1,…)];

• load data:表示加载数据
• local:表示从本地加载数据到hive 表；否则从HDFS 加载数据到hive 表
• inpath:表示加载数据的路径
• overwrite:表示覆盖表中已有数据，否则表示追加
• into table:表示加载到哪张表
• student:表示具体的表
• partition:表示上传到指定分区

hive (default)> create table student(id string, name string) row format delimited fields terminated by '\t';

-- 加载本地文件到hive
hive (default)> load data local inpath '/opt/module/datas/student.txt' into table default.student;
-- 加载HDFS 文件到hive 中
hive (default)> dfs -put /opt/module/datas/student.txt /user/atguigu/hive;
hive (default)> load data inpath '/user/atguigu/hive/student.txt' into table default.student;

-- 加载数据覆盖表中已有的数据
hive (default)> load data inpath '/user/atguigu/hive/student.txt' overwrite into table default.student;

通过查询语句向表中插入数据（Insert）

hive (default)> create table student(id int, name string) partitioned by (month string) row format delimited fields terminated by '\t';

-- 基本插入数据
hive (default)> insert into table student partition(month='201709') values(1,'wangwu');

-- 基本模式插入（根据单张表查询结果）
hive (default)> insert overwrite table student partition(month='201708') 
    select id, name from student where month='201709';

-- 多插入模式（根据多张表查询结果）
hive (default)> 
from student 
insert overwrite table student partition(month='201707')
    select id, name where month='201709'
insert overwrite table student partition(month='201706')
    select id, name where month='201709';

查询语句中创建表并加载数据（As Select）

根据查询结果创建表（查询的结果会添加到新创建的表中）

create table if not exists student3 as select id, name from student;

创建表时通过Location 指定加载数据路径

-- 创建表，并指定在hdfs 上的位置
hive (default)> create table if not exists student5(id int, name string)
row format delimited fields terminated by '\t'
location '/user/hive/warehouse/student5';

-- 上传数据到hdfs 上
hive (default)> dfs -put /opt/module/datas/student.txt /user/hive/warehouse/student5;

-- 查询数据
hive (default)> select * from student5;

Import 数据到指定Hive 表中

注意：先用export 导出后，再将数据导入。

可以直接导入不存在的表

hive (default)> import table student2 partition(month='201709') from '/user/hive/warehouse/export/student';

数据导出

Insert 导出

-- 将查询的结果导出到本地，local directory 这个代表本地文件
hive (default)> insert overwrite local directory '/opt/module/datas/export/student'
select * from student;

-- 将查询的结果格式化导出到本地
hive(default)>insert overwrite local directory '/opt/module/datas/export/student1'
ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t'
select * from student;

-- 将查询的结果导出到HDFS 上(没有local)
hive (default)> insert overwrite directory '/user/atguigu/student2' 
ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t' 
select * from student;

Hadoop 命令导出到本地

hive (default)> dfs -get /user/hive/warehouse/student/month=201709/000000_0 /opt/module/datas/export/student3.txt;

Hive Shell 命令导出

基本语法：（hive -f/-e 执行语句或者脚本> file）

-e 执行语句

-f 执行sql脚本

[atguigu@hadoop102 hive]$ bin/hive -e 'select * from default.student;' > /opt/module/datas/export/student4.txt;

Export 导出到HDFS 上

(defahiveult)> export table default.student to '/user/hive/warehouse/export/student';

清除表中数据

注意：Truncate 只能删除管理表，不能删除外部表中数据。只清除数据，不清除元数据

hive (default)> truncate table student;