Hive04-DDL

NiuMT 2020-07-03 20:58:30

Hive

创建数据库

hive> create database if not exists db_hive; 
-- 默认存储路径是/user/hive/warehouse/*.db。

hive> create database db_hive2 location '/db_hive2.db';
hive> create database db_hive2 location '/hive/db';
-- 指定数据库在HDFS 上存放的位置
-- 路径和数据库名可以不一致

查询数据库

-- 显示数据库
hive> show databases; 
-- 过滤显示查询的数据库
hive> show databases like 'db_hive*'; 
-- 显示数据库信息
hive> desc database db_hive;  
OK
db_hive
hdfs://hadoop102:9000/user/hive/warehouse/db_hive.db
atguiguUSER
-- 显示数据库详细信息
hive> desc database extended db_hive; 
OK
db_hive
hdfs://hadoop102:9000/user/hive/warehouse/db_hive.db
atguiguUSER

修改数据库

用户可以使用ALTER DATABASE 命令为某个数据库的DBPROPERTIES 设置键-值对属性值，来描述这个数据库的属性信息。数据库的其他元数据信息都是不可更改的，包括数据库名和数据库所在的目录位置。只能修改自定义的属性，其他属性不能修改。

hive> alter database hive set dbproperties('createtime'='20170830');

hive> desc database extended db_hive;
db_name comment location owner_name owner_type parameters
db_hive
hdfs://hadoop102:8020/user/hive/warehouse/db_hive.db
atguigu USER {createtime=20170830}

删除数据库

-- 删除空数据库
hive> drop database db_hive2; 
-- 如果删除的数据库不存在，最好采用if exists 判断数据库是否存在
hive> drop database if exists db_hive2;
-- 如果数据库不为空，可以采用cascade 命令，强制删除
hive> drop database db_hive cascade;

创建表

CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name
[(col_name data_type [COMMENT col_comment], ...)]
[COMMENT table_comment]
[PARTITIONED BY (col_name data_type [COMMENT col_comment], ...)]
[CLUSTERED BY (col_name, col_name, ...)
[SORTED BY (col_name [ASC|DESC], ...)] INTO num_buckets BUCKETS]
[ROW FORMAT row_format]
[STORED AS file_format]
[LOCATION hdfs_path]

CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。
EXTERNAL 关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际数据的路径（LOCATION），Hive 创建内部表时，会将数据移动到数据仓库指向的路径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。
COMMENT：为表和列添加注释。
PARTITIONED BY 创建分区表
CLUSTERED BY 创建分桶表
SORTED BY 不常用
ROW FORMAT

DELIMITED [FIELDS TERMINATED BY char] [COLLECTION ITEMS TERMINATED BY char]
[MAP KEYS TERMINATED BY char] [LINES TERMINATED BY char]
| SERDE serde_name [WITH SERDEPROPERTIES (property_name=property_value, property_name=property_value, ...)]

用户在建表的时候可以自定义SerDe 或者使用自带的SerDe。如果没有指定ROW FORMAT 或者ROW FORMAT DELIMITED，将会使用自带的SerDe。在建表的时候，用户还需要为表指定列，用户在指定表的列的同时也会指定自定义的SerDe，Hive 通过SerDe确定表的具体的列的数据。

SerDe 是Serialize/Deserilize 的简称，目的是用于序列化和反序列化。

STORED AS 指定存储文件类型

常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、RCFILE（列式存储格式文件）

如果文件数据是纯文本，可以使用STORED AS TEXTFILE。如果数据需要压缩，使用 STORED AS SEQUENCEFILE。
LOCATION ：指定表在HDFS 上的存储位置。
LIKE 允许用户复制现有的表结构，但是不复制数据

管理表(内部表)

默认创建的表都是所谓的管理表，有时也被称为内部表。因为这种表，Hive 会（或多或少地）控制着数据的生命周期。Hive 默认情况下会将这些表的数据存储在由配置项hive.metastore.warehouse.dir (如，/user/hive/warehouse)所定义的目录的子目录下。当我们删除一个管理表时，Hive 也会删除这个表中数据。管理表不适合和其他工具共享数据。

-- 普通创建表
create table if not exists student2(
id int, name string)
row format delimited fields terminated by '\t'
stored as textfile
location '/user/hive/warehouse/student2';

-- 根据查询结果创建表（查询的结果会添加到新创建的表中）
create table if not exists student3 as select id, name from student;

-- 根据已经存在的表结构创建表
create table if not exists student4 like student;

-- 查询表的类型
hive (default)> desc formatted student2;
Table Type: MANAGED_TABLE

外部表 (元数据+表)

因为表是外部表，所以Hive 并非认为其完全拥有这份数据。删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉。删除后再建立相同的表（即恢复元数据），不导入数据，依然能查到原来的数据。

每天将收集到的网站日志定期流入HDFS 文本文件。在外部表（原始日志表）的基础上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过SELECT+INSERT 进入内部表。

create external table if not exists default.dept(
deptno int,
dname string,
loc int )
row format delimited fields terminated by '\t';

load data local inpath '/opt/module/data/dept.txt' into table default.dept;

hive (default)> desc formatted dept;
Table Type: EXTERNAL_TABLE

管理表与外部表的互相转换

-- 修改内部表student2 为外部表
alter table student2 set tblproperties('EXTERNAL'='TRUE'); # 必须大写

-- 修改外部表student2 为内部表
alter table student2 set tblproperties('EXTERNAL'='FALSE');

分区表

分区表实际上就是对应一个HDFS 文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。Hive 中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。在查询时通过WHERE 子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多。

-- 需要根据日期对日志进行管理
/user/hive/warehouse/log_partition/20170702/20170702.log
/user/hive/warehouse/log_partition/20170703/20170703.log
/user/hive/warehouse/log_partition/20170704/20170704.log

-- 创建分区表
hive (default)> create table dept_partition(
deptno int, dname string, loc string )
partitioned by (month string)
row format delimited fields terminated by '\t';

-- 加载数据到分区表中
hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201709');
hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201708');
hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201707’);

-- 查询分区表中数据
hive (default)> select * from dept_partition where month='201709';

-- 多分区联合查询
hive (default)> select * from dept_partition  where month='201709'
union
select * from dept_partition where month='201708'
union
select * from dept_partition where month='201707';

_u3.deptno _u3.dname _u3.loc _u3.month
10 ACCOUNTING NEW YORK 201707
10 ACCOUNTING NEW YORK 201708
10 ACCOUNTING NEW YORK 201709
20 RESEARCH DALLAS 201707
20 RESEARCH DALLAS 201708
20 RESEARCH DALLAS 201709
30 SALES CHICAGO 201707
30 SALES CHICAGO 201708
30 SALES CHICAGO 201709
40 OPERATIONS BOSTON 201707
40 OPERATIONS BOSTON 201708
40 OPERATIONS BOSTON 201709

-- 增加分区
hive (default)> alter table dept_partition add partition(month='201706') ;
hive (default)> alter table dept_partition add partition(month='201705') partition(month='201704');

-- 删除分区
hive (default)> alter table dept_partition drop partition (month='201704');
hive (default)> alter table dept_partition drop partition (month='201705'), partition (month='201706');

-- 查看分区表有多少分区
hive> show partitions dept_partition;

-- 查看分区表结构
hive> desc formatted dept_partition;
-- # Partition Information
-- # col_name data_type comment
month string

-- 创建二级分区表
hive (default)> create table dept_partition2(
deptno int, dname string, loc string )
partitioned by (month string, day string)
row format delimited fields terminated by '\t';

-- 加载数据到二级分区表中
hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition2 partition(month='201709', day='13');

-- 查询分区数据
hive (default)> select * from dept_partition2 where month='201709' and day='13';

把数据直接上传到分区目录上，让分区表和数据产生关联的三种方式：

上传数据后修复

-- 上传数据
hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=12;
hive (default)> dfs -put /opt/module/datas/dept.txt /user/hive/warehouse/dept_partition2/month=201709/day=12;

 -- 查询数据（查询不到刚上传的数据）
hive (default)> select * from dept_partition2 where month='201709' and day='12';

-- 执行修复命令
hive> msck repair table dept_partition2;

上传数据后添加分区

-- 上传数据
hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=11;
hive (default)> dfs -put /opt/module/datas/dept.txt /user/hive/warehouse/dept_partition2/month=201709/day=11;

-- 执行添加分区
hive (default)> alter table dept_partition2 add partition(month='201709', day='11');

创建文件夹后load 数据到分区

-- 创建目录
hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=10;

-- 上传数据
hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table dept_partition2 partition(month='201709',day='10');

修改表

-- 重命名
ALTER TABLE table_name RENAME TO new_table_name

-- 增加/修改/替换列信息
-- 更新列，可以更改列名和列的数据类型，即使不修改类型也要写上
ALTER TABLE table_name CHANGE [COLUMN] col_old_name col_new_name column_type [COMMENT col_comment] [FIRST|AFTER column_name]
-- 增加和替换列
-- ADD 是代表新增一字段，字段位置在所有列后面(partition 列前)，REPLACE 则是表示替换表中所有字段
ALTER TABLE table_name ADD|REPLACE COLUMNS (col_name data_type [COMMENT col_comment], ...)
-- alter table xixi replace colums(id int, name string).
-- 把所有字段替换为两个字段，相当于至保留前两个字段，修改了元数据，但没有修改HDFS上的文件。如果多加列，数据会显示为null。HDFS上文件没有添加相应字段的数据

hive (default)> alter table dept_partition add columns(deptdesc string); # 添加列
hive (default)> alter table dept_partition change column deptdesc desc int; # 更新列
hive (default)> alter table dept_partition replace columns(deptno string, dname string, loc string); # 替换列

删除表

hive (default)> drop table dept_partition;

Hive03-数据类型

Hive06-查询